summaryrefslogtreecommitdiffstats
path: root/acc.asm
blob: 23c0b4d8aab81b7b700c2e5b24a540254393411f (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
/* -*- asm -*- ----------------------------------------------------------- *
 *   
 *   Copyright 2013 H. Peter Anvin - All Rights Reserved
 *
 *   Permission is hereby granted, free of charge, to any person
 *   obtaining a copy of this software and associated documentation
 *   files (the "Software"), to deal in the Software without
 *   restriction, including without limitation the rights to use,
 *   copy, modify, merge, publish, distribute, sublicense, and/or
 *   sell copies of the Software, and to permit persons to whom
 *   the Software is furnished to do so, subject to the following
 *   conditions:
 *   
 *   The above copyright notice and this permission notice shall
 *   be included in all copies or substantial portions of the Software.
 *   
 *   THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
 *   EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
 *   OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
 *   NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
 *   HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
 *   WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
 *   FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
 *   OTHER DEALINGS IN THE SOFTWARE.
 *
 * ----------------------------------------------------------------------- */

#include "v9fs.h"

	.code16
	.section ".rtext","ax"

/* ------------------------------------------------------------------------- *
 *  acc_always
 *
 *  Always accept an incoming request.
 * ------------------------------------------------------------------------- */

	.globl acc_always
acc_always:
	clc
	retw

	.size acc_always,.-acc_always
	.type acc_always,@function

/* ------------------------------------------------------------------------- *
 *  acc_file
 *
 *  Check drive in the System File Table
 * ------------------------------------------------------------------------- */

	.globl acc_file
acc_file:
	movw F_DI,%si
	movw F_ES,%fs
	addw $SFT_DEVINFO,%si		/* Byte 5 in SFT entry = drive */
	/* fall through */
	.size acc_file,.-acc_file
	.type acc_file,@function

	/*
	 * Available for multiple users of a modified drive number
	 * at %fs:(%si)	- specifically a zero-based drive number where
	 * bit 6 is expected to be set for a conforming redirector.
	 */
acc_drive_common:
	movb %fs:(%si),%al		/* Device info word (low half) */
	andb $0x5f,%al			/* Drive number + conforming bit (6) */
	incw %ax
	cmpb drive_letter,%al
	jne acc_fail
	/* CF = 0 if equal */
	retw
	.size acc_drive_common,.-acc_drive_common
	.type acc_drive_common,@function

/* ------------------------------------------------------------------------- *
 *  acc_findnext
 * ------------------------------------------------------------------------- */

	.globl acc_findnext
acc_findnext:
	lfsw dos_sdafn,%si
	addw $SDN_SEARCHDATA,%si	/* First byte in srcrec = drive no */
	jmp acc_drive_common

	.size acc_findnext,.-acc_findnext
	.type acc_findnext,@function

/* ------------------------------------------------------------------------- *
 *  acc_never
 *
 *  This is never for us; either we don't support it or we don't do
 *  anything with it anyway.
 * ------------------------------------------------------------------------- */

	.globl acc_never
acc_never:
acc_fail:				/* Used as common tail */
	stc
	retw

	.size acc_never,.-acc_never
	.type acc_never,@function

	.globl fxn_unknown
fxn_unknown	= acc_never

/* ------------------------------------------------------------------------- *
 *  acc_cds
 *
 *  The SDA contains a copy of the CDS for the current access - use it to
 *  determine if this is for us.
 * ------------------------------------------------------------------------- */

	.globl acc_cds
acc_cds:
	lfsw dos_sdafn,%si
	addw $SDN_CDS,%si
	cmpw $CDS_MAGIC,%fs:CDS_DPBPTR(%si)	/* Our magic? */
	jne acc_fail
	movb drive_letter,%al
	cmpb %al,%fs:(CDS_PATH+0)(%si)		/* Our drive letter? */
	jne acc_fail
	cmpw $0x5c3a,%fs:(CDS_PATH+1)(%si)	/* Path starts with X:\? */
	jne acc_fail
	/* XXX: check for a character device */
	/* CF = 0 if equal */
	retw

	.size acc_cds,.-acc_cds
	.type acc_cds,@function

/* ------------------------------------------------------------------------- *
 *  acc_qualify
 * ------------------------------------------------------------------------- */

	.globl acc_qualify
acc_qualify:
	movw F_SI,%si
	movw F_DS,%fs
	jmp acc_drive_common

	.size acc_qualify,.-acc_qualify
	.type acc_qualify,@function