aboutsummaryrefslogtreecommitdiffstats
diff options
context:
space:
mode:
authorThomas Schwinge <thomas@schwinge.name>2012-05-10 12:47:31 -0700
committerRoland McGrath <roland@hack.frob.com>2012-05-10 15:57:22 -0700
commitbcf5524012216fee3a7668a3b43aad3243a083b0 (patch)
tree88c2c8d57cfcfb8d920508f9c9d7378dc88c0bd6
parent6178c55bdbb1e434b594e5f8563b6948f8f3edc0 (diff)
downloadtermbaud-bcf5524012216fee3a7668a3b43aad3243a083b0.tar.gz
termbaud-bcf5524012216fee3a7668a3b43aad3243a083b0.tar.xz
termbaud-bcf5524012216fee3a7668a3b43aad3243a083b0.zip
Hurd: ____longjmp_chk
-rw-r--r--ChangeLog7
-rw-r--r--sysdeps/mach/hurd/i386/Makefile4
-rw-r--r--sysdeps/mach/hurd/i386/____longjmp_chk.S107
-rw-r--r--sysdeps/mach/hurd/i386/signal-defines.sym10
4 files changed, 128 insertions, 0 deletions
diff --git a/ChangeLog b/ChangeLog
index 976aa1e92d2..9aa8753a488 100644
--- a/ChangeLog
+++ b/ChangeLog
@@ -1,3 +1,10 @@
+2012-05-10 Thomas Schwinge <thomas@schwinge.name>
+
+ * sysdeps/mach/hurd/i386/____longjmp_chk.S: New file.
+ * sysdeps/mach/hurd/i386/signal-defines.sym: New file.
+ * sysdeps/mach/hurd/i386/Makefile (gen-as-const-headers): Add
+ signal-defines.sym.
+
2012-05-10 Samuel Thibault <samuel.thibault@ens-lyon.org>
* bits/in.h (SOL_IP, SOL_IPV6, SOL_ICMPV6): New macros.
diff --git a/sysdeps/mach/hurd/i386/Makefile b/sysdeps/mach/hurd/i386/Makefile
index 0eef17e8f2c..5f988097c24 100644
--- a/sysdeps/mach/hurd/i386/Makefile
+++ b/sysdeps/mach/hurd/i386/Makefile
@@ -2,3 +2,7 @@ ifeq ($(subdir),misc)
sysdep_routines += ioperm
sysdep_headers += sys/io.h
endif
+
+ifeq ($(subdir),debug)
+gen-as-const-headers += signal-defines.sym
+endif
diff --git a/sysdeps/mach/hurd/i386/____longjmp_chk.S b/sysdeps/mach/hurd/i386/____longjmp_chk.S
new file mode 100644
index 00000000000..f499fbd1e71
--- /dev/null
+++ b/sysdeps/mach/hurd/i386/____longjmp_chk.S
@@ -0,0 +1,107 @@
+/* Copyright (C) 2001-2012 Free Software Foundation, Inc.
+ This file is part of the GNU C Library.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library; if not, see
+ <http://www.gnu.org/licenses/>. */
+
+#include <sysdep.h>
+#include <jmpbuf-offsets.h>
+#include <asm-syntax.h>
+
+#include <signal-defines.h>
+/* #include <signal.h> */
+#define SS_ONSTACK 1
+
+
+ .section .rodata.str1.1,"aMS",@progbits,1
+ .type longjmp_msg,@object
+longjmp_msg:
+ .string "longjmp causes uninitialized stack frame"
+ .size longjmp_msg, .-longjmp_msg
+
+
+#ifdef PIC
+# define CALL_FAIL movl %ebx, %ecx; /* TODO: what's this mov good for? */ \
+ cfi_register(%ebx,%ecx); \
+ LOAD_PIC_REG (bx); \
+ leal longjmp_msg@GOTOFF(%ebx), %eax; \
+ call HIDDEN_JUMPTARGET(__fortify_fail)
+#else
+# define CALL_FAIL movl $longjmp_msg, %eax; \
+ call HIDDEN_JUMPTARGET(__fortify_fail)
+#endif
+
+
+ .text
+ENTRY (____longjmp_chk)
+ movl 4(%esp), %ecx /* User's jmp_buf in %ecx. */
+
+ /* Save the return address now. */
+ movl (JB_PC*4)(%ecx), %edx
+ /* Get the stack pointer. */
+ movl (JB_SP*4)(%ecx), %edi
+ cfi_undefined(%edi)
+ PTR_DEMANGLE (%edx)
+ PTR_DEMANGLE (%edi)
+
+ cmpl %edi, %esp
+ /* Jumping to a higher-address frame is always allowed. */
+ jbe .Lok
+
+ /* Passing here, we're either about to do something invalid, or we're
+ executing on an alternative signal stack. */
+
+ /* TODO: need locking? */
+ /* struct hurd_sigstate * _hurd_self_sigstate (void) */
+ call _hurd_self_sigstate
+ /* TODO: %eax and %eax->sigaltstack are always valid? */
+
+ testl $SS_ONSTACK, (HURD_SIGSTATE__SIGALTSTACK__OFFSET + SIGALTSTACK__SS_FLAGS__OFFSET)(%eax)
+ /* Fail if SS_ONSTACK is not set. */
+ jz .Lfail
+
+ movl (HURD_SIGSTATE__SIGALTSTACK__OFFSET + SIGALTSTACK__SS_SP__OFFSET)(%eax), %ebx
+ addl (HURD_SIGSTATE__SIGALTSTACK__OFFSET + SIGALTSTACK__SS_SIZE__OFFSET)(%eax), %ebx
+ subl %edi, %ebx
+ cmpl (HURD_SIGSTATE__SIGALTSTACK__OFFSET + SIGALTSTACK__SS_SIZE__OFFSET)(%eax), %ebx
+ /* TODO: comment this calculation. */
+ jae .Lok
+
+.Lfail: CALL_FAIL
+
+.Lok: /* We add unwind information for the target here. */
+ cfi_def_cfa(%ecx, 0)
+ cfi_register(%eip, %edx)
+ cfi_register(%esp, %edi)
+ cfi_offset(%ebx, JB_BX*4)
+ cfi_offset(%esi, JB_SI*4)
+ cfi_offset(%edi, JB_DI*4)
+ cfi_offset(%ebp, JB_BP*4)
+
+ movl 8(%esp), %eax /* Second argument is return value. */
+ movl %edi, %esp
+
+ /* Restore registers. */
+ movl (JB_BX*4)(%ecx), %ebx
+ movl (JB_SI*4)(%ecx), %esi
+ movl (JB_DI*4)(%ecx), %edi
+ movl (JB_BP*4)(%ecx), %ebp
+ cfi_restore(%ebx)
+ cfi_restore(%esi)
+ cfi_restore(%edi)
+ cfi_restore(%ebp)
+
+ /* Jump to saved PC. */
+ jmp *%edx
+END (____longjmp_chk)
diff --git a/sysdeps/mach/hurd/i386/signal-defines.sym b/sysdeps/mach/hurd/i386/signal-defines.sym
new file mode 100644
index 00000000000..9521bd723cf
--- /dev/null
+++ b/sysdeps/mach/hurd/i386/signal-defines.sym
@@ -0,0 +1,10 @@
+#include <hurd/signal.h>
+#include <signal.h>
+
+--
+
+HURD_SIGSTATE__SIGALTSTACK__OFFSET offsetof(struct hurd_sigstate, sigaltstack)
+
+SIGALTSTACK__SS_SP__OFFSET offsetof(struct sigaltstack, ss_sp)
+SIGALTSTACK__SS_SIZE__OFFSET offsetof(struct sigaltstack, ss_size)
+SIGALTSTACK__SS_FLAGS__OFFSET offsetof(struct sigaltstack, ss_flags)